calculate the average color in an image

<!-- METADATA TYPE="typelib" UUID="{3CE48541-DE7A-4909-9314-9D0ED0D1CA5A}"-->
<%
Option Explicit

Dim objBitmap
'Create Bitmap object
Set objBitmap = Server.CreateObject("GraphicsMill.Bitmap")

objBitmap.LoadFromFile Server.MapPath("building.jpg")

Dim lngAvgRed, lngAvgGreen, lngAvgBlue
Dim arrHistogram, I, lngAvgColor

'Get histogram for each channel to calculate average
'intensity of an appropriate channel.

'To do it, get sum of elements of histogram multiplied
'on appropriate intensity
arrHistogram=objBitmap.Data.GetHistogram(ChannelRed)
lngAvgRed = 0
For I=0 To 255
	lngAvgRed = lngAvgRed + I * arrHistogram(I)
Next

'After that, normalize this sum on the amount of pixels. 
'Total amount of pixels equals width * height 
lngAvgRed = Round(lngAvgRed / (objBitmap.Data.Width * objBitmap.Data.Height))

'Do the same for green and blue channels
arrHistogram=objBitmap.Data.GetHistogram(ChannelGreen)
lngAvgGreen = 0
For I=0 To 255
	lngAvgGreen = lngAvgGreen + I * arrHistogram(I)
Next
lngAvgGreen = Round(lngAvgGreen / (objBitmap.Data.Width * objBitmap.Data.Height))

arrHistogram=objBitmap.Data.GetHistogram(ChannelBlue)
lngAvgBlue = 0
For I=0 To 255
	lngAvgBlue = lngAvgBlue + I * arrHistogram(I)
Next
lngAvgBlue = Round(lngAvgBlue / (objBitmap.Data.Width * objBitmap.Data.Height))

'After we calculate average intensities of each channel,
'combine them into one RGB color.
lngAvgColor = objBitmap.Color.CreateRgb(lngAvgRed, lngAvgGreen, lngAvgBlue) 

'Display this color. Let's draw the square 30x30 filled with average color 
'we calculated. 
objBitmap.Graphics.Brush.PrimaryColor = lngAvgColor
objBitmap.Graphics.DrawRectangle 10, 10, 30, 30, True, True

objBitmap.SaveToStream Response
%>