Welcome Guest! You need to login or register to make posts.

Notification

Icon
Error

Options
Go to last post Go to first unread
bcrosby  
#1 Posted : Wednesday, April 28, 2004 10:54:00 PM(UTC)
bcrosby

Rank: Member

Groups: Member
Joined: 4/28/2004(UTC)
Posts: 1

Hi,
I've installed everything according to instructions and my upload page is displaying but I keep getting a "connection was interrupted" message whenever I try to upload an image.
I know this is not the case as I'm testing this product on a development machine using localhost.
What are the causes of this error message? I've searched forums, KB, help files and internet trying to find a solution.
Also,
Will this product work with Software Artisans FileUp product? Or do I have to write the code and submit it?
Thanks
Brett
Fedor  
#2 Posted : Wednesday, April 28, 2004 11:18:00 PM(UTC)
Fedor

Rank: Advanced Member

Groups: Member, Administration, Moderator
Joined: 7/28/2003(UTC)
Posts: 1,545

Thanks: 5 times
Was thanked: 58 time(s) in 57 post(s)
>>"connection was interrupted"

This problem can be concerned with incorrect server configuration (limit of max file upload and so on) or server-side scripts error. To check server try to upload files smaller 80kb totally, and Image Uploader should show more detailed error.

>>Will this product work with Software Artisans FileUp product? Or do I have to write the code and submit it?

Image Uploader should work with Software Artisans FileUp as both of them are RFC 1867 compatible, however we ship Image Uploader without samples for it , but I will post sample for FileUp here in the nearest time.
Best regards,
Fedor Skvortsov
Fedor  
#3 Posted : Sunday, May 02, 2004 7:18:00 PM(UTC)
Fedor

Rank: Advanced Member

Groups: Member, Administration, Moderator
Joined: 7/28/2003(UTC)
Posts: 1,545

Thanks: 5 times
Was thanked: 58 time(s) in 57 post(s)
Here is sample for Software Artisans FileUp in ASP:

Code:
<%
' Aurigma Image Uploader Sample Script
' WWW: http://www.aurigma.com

Server.ScriptTimeout = 450

'Modify this block, according to your needs.
Dim strGalleryPath, strConnectionString, MyConnection

'This variable specifies a relative path to the folder, where image gallery is located.
'Don't forget to add slash at the end of the path
strGalleryPath = "../Gallery/"

'Connection string to database with image descriptions
strConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & _
	Server.MapPath("../DB/Demo.mdb") & ";"

'Create Connection
Set MyConnection = Server.CreateObject("ADODB.Connection") 
MyConnection.Open strConnectionString

'We delete all files and descriptions for old files
Dim objFileSystem, objFolder, objSubFolder, objFile
Set objFileSystem = Server.CreateObject("Scripting.FileSystemObject")

'Delete source images
Set objFolder = objFileSystem.GetFolder(Server.MapPath(strGalleryPath))
For Each objFile In objFolder.Files
	objFileSystem.DeleteFile objFile.Path, True
Next

'Delete thumbnails
Set objFolder = objFileSystem.GetFolder(Server.MapPath(strGalleryPath) & "\Thumbnails")
For Each objFile In objFolder.Files
	objFileSystem.DeleteFile objFile.Path, True
Next

'Delete descriptions from database
MyConnection.Execute "DELETE FROM [File]"

'Process upload
Dim objUpload
Dim intFileCount, I 
Dim strAuthor  
        
'We create aspSmartUpload object for uploading images        
Set objUpload = Server.CreateObject("SoftArtisans.FileUp")
objUpload.MaxBytesToCancel = 20971520
objUpload.Path = Server.MapPath(strGalleryPath)

'We create command for adding items in database
Dim MyCommand
Set MyCommand = Server.CreateObject("ADODB.Command")
MyCommand.ActiveConnection = MyConnection
MyCommand.CommandText = "INSERT INTO [File](Name, Width, Height, Author, Description) " & _
		"VALUES (?, ?, ?, ?, ?)"
'Add parameters to collection
Dim ParameterName, ParameterWidth, ParameterHeight, ParameterAuthor, ParameterDescription
Set ParameterName = MyCommand.CreateParameter("Name", 200, 1, 50)
MyCommand.Parameters.Append ParameterName
Set ParameterWidth = MyCommand.CreateParameter("Width", 3, 1)
MyCommand.Parameters.Append ParameterWidth
Set ParameterHeight = MyCommand.CreateParameter("Height", 3, 1)
MyCommand.Parameters.Append ParameterHeight
Set ParameterAuthor = MyCommand.CreateParameter("Author", 200, 1, 50)
MyCommand.Parameters.Append ParameterAuthor
Set ParameterDescription = MyCommand.CreateParameter("Description", 200, 1, 255)
MyCommand.Parameters.Append ParameterDescription

'Set Author parameter value
ParameterAuthor.Value = objUpload.Form("Author")

'Total amount of uploaded files
intFileCount = objUpload.Form("FileCount")

'We run over uploaded images and load it
For I=1 To intFileCount
	'Fetch source images and save it to disk
	Set objFile = objUpload.Form("SourceFile_" & I)
	Dim strFileName, strNewFileName
	strFileName = objFile.ShortFilename 
	strNewFileName = strFileName
	'Check whether file with such name already exists and if so, 
	'construct safe filename name (to avoid collision)
	Dim J 
	J = 1
	While objFileSystem.FileExists(Server.MapPath(strGalleryPath & strNewFileName))
		strNewFileName = J & "_" & strFileName
		J = J + 1
	Wend
	strFileName = strNewFileName	
	objFile.SaveAs (Server.MapPath(strGalleryPath & strFileName))
	'Fetch thumbnails and save it to disk
	Set objFile = objUpload.Form("Thumbnail1_" & I)
	objFile.SaveAs (Server.MapPath(strGalleryPath & "Thumbnails/" & strFileName & ".jpg"))
	'Save description in database
	ParameterName.Value = strFileName
	ParameterDescription.Value = objUpload.Form("Description_" & I)
	ParameterWidth.Value = objUpload.Form("Width_" & I)
	ParameterHeight.Value = objUpload.Form("Height_" & I)		
	MyCommand.Execute
Next

'Clean up
MyConnection.Close
%>

Edited by user Friday, May 23, 2008 4:16:12 PM(UTC)  | Reason: Not specified

Best regards,
Fedor Skvortsov
Users browsing this topic
Similar Topics
Connection Interrupted & version 3.5 (Discussions – ActiveX/Java Uploader)
by jeromewilson 2/14/2005 1:19:00 AM(UTC)
diagnosing "connection interrupted" errors (Image Uploader)
by pcoley 11/11/2004 4:28:00 AM(UTC)
getting connection interrupted message after 5 minutes of (Image Uploader)
by quattro 10/26/2004 10:30:00 AM(UTC)
Connection Interrupted (Image Uploader)
by krishenn 10/12/2004 11:41:00 PM(UTC)
Forum Jump  
You cannot post new topics in this forum.
You cannot reply to topics in this forum.
You cannot delete your posts in this forum.
You cannot edit your posts in this forum.
You cannot create polls in this forum.
You cannot vote in polls in this forum.